مدیریت وسایل برقی از هر مکان با دستیار صوتی گوگل و برد Nodemcu

تصور کنید  زمانی که از سرکار به سمت خونه حرکت می کنید قبل رسیدن به خانه فر برقی را روشن می کنید و غذای شما  گرم و آماده ی میل کردن است و یا اینکه قبل از اینکه برسید خونه کولر را روشن کرده اید تا هوای خانه خنک شود و بسیاری کارهای دیگه ای را می توانید انجام دهید.شاید در نگاه اول کاری رویایی و غیر واقعی به نظر برسد ولی این کار شدنی است . برای این کار شما نیاز به یک برد NODEMCU و حسابی در سایت adafruit و Gmail دارید شما می توانید با فرمان های صوتی یا فرمان های دستی اشیاء مربوطه را مدیریت نمایید در ادامه تمامی مراحل بصورت کامل توضیح داده خواهد شد.

لوازم مورد نیاز:

برد NodeMcu بر پایه تراشه ESP8266

ماژول رله Relay (تکی یا ۴ تایی یا ۸ تایی و… با توجه به تعداد خروجی های مورد نیاز انتخاب کنید)

اتصالات:

همانطور که در تصویر مشاهده می کنید با استفاده از یک منبع DC 5v ماند آردوینو اونو یا یک منبع دست ساز , پین ۳٫۳v برد NodeMcu را به ۳٫۳v آردوینو متصل میکنیم و Vcc ماژول رله خود را به ۵v متصل می کنیم پایه D1 برد NodeMcu را به پایه ی IN1 ماژول رله متصل می کنیم وپایه D2 برد NodeMcu را به پایه ی IN2 ماژول رله متصل می کنیم و پایه D3 برد NodeMcu را به پایه ی IN3 ماژول رله متصل می کنیم و پایه D4برد NodeMcu را به پایه یIN4 ماژول رله متصل می کنیم  و پایه های GND را به پایه ی GND منبع متصل می کنیم.

کتابخانه‌های مورد نیاز

کتابخانه ی زیر بصورت پیش فرض در برد nodemcu موجود است

#include <ESP8266WiFi.h>

کتابخانه ی زیر را را در آخر همین پست بارگیری نمایید.

#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

۱- پروتکل MQTT ارتباط امن در IoT

با استفاده از حساب کاربری که در سایت Adafruit  ساخته‌اید، به برد Nodemcu متصل شوید. با متصل کردن نام کاربری و توکن حساب کاربری‌تان به برد NodeMcu اشیاء را مدیریت کنید. با دستور دادن در سایت مربوطه آن دستور را به برد انتقال داده و رله مورد نظر خاموش یا روشن خواهد شد. ابتدا باید در سایت io.adafruit.com حساب کاربری ایجاد نمایید. برای این منظور وارد لینک آدافروت شوید. روی Sign In کلیک کرده سپس روی گزینه‌ی Sign Up کلیک و حساب کاربری ایجاد نمایید. در تصاویر زیر هم مشخص شده است.

بعد از ساخت حساب کاربری وارد شوید. ابتدا روی گزینه‌ی dashboard کلیک نموده و سپس روی گزینه‌ی action کلیک کنید. بعد از آن روی create new dashboard کلیک کنید. هر نامی که علاقه دارید، روی آن بگذارید سپس روی create کلیک بنمایید.

سپس روی داشبوردی که ساخته‌اید کلیک کنید. روی علامت بعلاوه در سمت راست بالای سایت کلیک کنید اولین بلاک را انتخاب کنید  زمانی که موس را روی آن برده در بالای آن toggle نمایان خواهد شد.

سپس باید feed بسازید که با کد نویسی که در Arduino Ide هم خوانی داشته باشد بطور مثال feed من Relay1 ساخته شد پس در کد نویسی هم باید از همین نام استفاده کنید.

Adafruit_MQTT_Subscribe Light1 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME"/feeds/Relay1"); // نام فیدها که در سایت وارد کرده اید
Adafruit_MQTT_Subscribe Light2 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/Relay2");
Adafruit_MQTT_Subscribe Light3 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/Relay3");
Adafruit_MQTT_Subscribe Light4 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/Relay4");

و بعد روی feed  که ساخته اید  کلیک نموده و روی next step کلیک کنید و در کادر block Title نام فید را بنویسید و در کادر دوم On را پاک کرده و عدد ۱ را بنویسید و در کادر سوم offرا پاک کرده و عدد ۰ را بنویسید سپس در پایین صفحه روی گزینه ی create block کلیک کنید و با توجه به تعداد اشیاء هایی که قصد دارید کنترل کنید feedsبسازید و همین عملیات  را تکرار نمایید. سپس روی علامت کلید که در سمت راست بالای سایت قرار دارد کلیک کرده User Name و Active Key را کپی کرده و بصورت زیر در کدنویسی که در Arduino Ide وجود دارد قرار دهید.

#define AIO_USERNAME    "   ----   "            // Username
#define AIO_KEY         "       -----      "   // Active Key

تا اینجا شما با استفاده از سایت Adafruit توانستید  اشیاء خود را بصورت دستی مدیریت کنید در مرحله ی بعد برای مدیریت صوتی اشیاء شما باید Adafruit را با دستیار صوتی گوگل همگام کنید.

۲- دستیار صوتی گوگل و IFTTT

بخش دوم پروژه مربوط به اپلیکیشن IFTTT خواهد بود. ابتدا باید حساب کاربری در Gmail ایجاد کنید. سپس وارد سایت IFTTT.com شوید. روی گزینه‌ی Continue With Google کلیک کنید. به صفحه Gmail هدایت می‌شوید. با حساب کاربری Gmail وارد شده و در بالای صفحه روی My Applet کلیک کنید. سپس روی New Applet کلیک کنید. بعد از آن نوشته‌ی بزرگی که if +this then that شما روی this+ که به رنگ آبی است کلیک کنید.

سپس در کادر search services باید دستیار صوتی گوگل را سرچ کنیم. پس Google Assistant سپس روی گزینه ی اول Say a simple phrase کلیک می کنیم.

در کادر اول What do you want to say دستور روشن شدن شی مربوطه را  بنویسید به طور مثال من turn on blue light را می نویسم سپس در کادر آخرWhat do you want the Assistant to say in response جوابی که به شما خواهد داد را بنویسید بطور مثال من Ok sir Reza seyyedzadeh turn on blue light را می نویسم و بعد روی create trigger کلیک  می کنم سپس روی نوشته ی that+ که به رنگ آبی است کلیک کنید و سپس Adafruit  را سرچ کنید و روی Send data to Adafruit IO کلیک کنید و شما در کادر اول نام feed هایی که ساخته اید را مشاهده می کنید فید مورد نظر را انتخاب کرده و به دلیل اینکه میخواهیم رله روشن شود پس در کادر اخر عدد ۱ رو مینویسم سپس روی create action کرده و بعد finish را کلیک کنید تا Applet شما ساخته شود برای خاموش کردن رله همین عملیات را باید انجام دهید فقط باید در قسمت دستور دادن از جمله ی turn off blue light استفاده کنید زمانی که تمام مراحل را انجام دادید در آخر در قسمت Date to save این بار عدد ۰ را بنویسید و Create action را اوکی کرده و سپس روی گزینه ی finish کلیک کرده تا Applet شما ساخته شود برای هرتعداد رله این دو مرحله ای که انجام دادید را باید برای بقیه رله ها هم انجام دهید.

ویدیو کامل اجرای مراحل

۳-کد نویسی برای مدیریت اشیاء

تمامی مراحل بالا را انجام داده سپس کد ها را روی برد NodeMcu آپلود می کنیم

کد

#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

#define Relay1            D1
#define Relay2            D2
#define Relay3            D3
#define Relay4            D4


#define WLAN_SSID       "   ----   "             // Your SSID
#define WLAN_PASS       "   ----   "        // Your password

/************************* Adafruit.io Setup *********************************/

#define AIO_SERVER      "io.adafruit.com" //Adafruit Server
#define AIO_SERVERPORT  1883                   
#define AIO_USERNAME    "   ----   "            // Username
#define AIO_KEY         "       -----      "   // Active Key

//WIFI CLIENT
WiFiClient client;

Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_KEY);

Adafruit_MQTT_Subscribe Light1 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME"/feeds/Relay1"); // نام فیدها که در سایت وارد کرده اید
Adafruit_MQTT_Subscribe Light2 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/Relay2");
Adafruit_MQTT_Subscribe Light3 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/Relay3");
Adafruit_MQTT_Subscribe Light4 = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/Relay4");


void MQTT_connect();

void setup() {
  Serial.begin(115200);

  pinMode(Relay1, OUTPUT);
  pinMode(Relay2, OUTPUT);
  pinMode(Relay3, OUTPUT);
  pinMode(Relay4, OUTPUT);

  
  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: "); 
  Serial.println(WiFi.localIP());
 
  mqtt.subscribe(&Light1);
  mqtt.subscribe(&Light3);
  mqtt.subscribe(&Light2);
  mqtt.subscribe(&Light4);

}


void loop() {
 
  MQTT_connect();
  

  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqtt.readSubscription(20000))) {
    if (subscription == &Light1) {
      Serial.print(F("Got: "));
      Serial.println((char *)Light1.lastread);
      int Light1_State = atoi((char *)Light1.lastread);
      digitalWrite(Relay1, Light1_State);
      
    }
    if (subscription == &Light2) {
      Serial.print(F("Got: "));
      Serial.println((char *)Light2.lastread);
      int Light2_State = atoi((char *)Light2.lastread);
      digitalWrite(Relay2, Light2_State);
    }
    if (subscription == &Light3) {
      Serial.print(F("Got: "));
      Serial.println((char *)Light3.lastread);
      int Light3_State = atoi((char *)Light3.lastread);
      digitalWrite(Relay3, Light3_State);
    }
    if (subscription == &Light4) {
      Serial.print(F("Got: "));
      Serial.println((char *)Light4.lastread);
      int Light4_State = atoi((char *)Light4.lastread);
      digitalWrite(Relay4, Light4_State);
      
    }
  }

  
}

void MQTT_connect() {
  int8_t ret;

  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  
  while ((ret = mqtt.connect()) != 0) {
    Serial.println(mqtt.connectErrorString(ret));
    Serial.println("Retrying MQTT connection in 5 seconds...");
    mqtt.disconnect();
    delay(5000); 
    retries--;
    if (retries == 0) {
      while (1);
    }
  }
  Serial.println("MQTT Connected!");
  
}

چنانچه در مراحل راه اندازی و انجام این پروژه با مشکل مواجه شدید، بدون هیچ نگرانی در انتهای همین پست، به صورت ثبت نظر سوالتان را مطرح کنید. من در سریع‌ترین زمان ممکن پاسخ رفع مشکل شما را خواهم داد. همچنین اگر ایرادی در کدها و یا مراحل اجرایی وجود دارند می‌توانید از همین طریق اطلاع رسانی کنید.

پروژه و دریافت بن ارسال رایگان

برای دریافت بن خرید از دانشجو کیت، کاربران بایستی با استفاده از وسایل این آموزش، پروژه را اجرا کرده و یا حتی مدار جدیدی تعریف کنید. سپس از اجرای کار فیلم گرفته و در شبکه‌های اجتماعی از جمله آپارات و اینستگرام، با هشتگ‌های دیجی_اسپارک و دانشجوکیت  و digispark  و  daneshjookit منتشر کنند. سپس از طریق بخش نظرات در ادامه همین آموزش، جهت دریافت بن خرید ارسال رایگان به ارزش ۱۰۳۰۰ تومان از دانشجو کیت، لینک را زیر همین پست ارسال کنید.

در پایان نظرات و پیشنهادات خود را با ما درمیان بگذارید و با اشتراک گذاری این آموزش در شبکه های اجتماعی , از وبسایت دیجی اسپارک حمایت کنید.