کنترل موس کامپیوتر با جوی استیک با استفاده از برد آردوینو Arduino

با استفاده از کتابخانه موس شما میتوانید موس کامیپوترتان را  توسط آردوینو های LEONARDO , DUE و MICRO  کنترل کنید.در این آموزش قصد داریم به کنترل موس کامپیوتر همراه با جوی استیک با استفاده از آردوینو لئوناردو بپردازیم.در ادامه با مرجع تخصصی آردوینو با دیجی اسپارک همراه باشید.

کنترل موس کامپیوتر با جوی استیک

در این پروژه با استفاده از یک جوی استیک دو محوره  و یک تاچ سوئیج یک موس واقعی را شبیه سازی میکنیم.حرکت نشان گر موس به مقدار های آنالوگ تولید شده توسط جوی استیک بستگی دارد.با استفاده از دو پین آنالوگ ، مقادیری بین ۰ الی ۱۰۲۳ دریافت میکنیم که با عملیاتی که تابع  readAxis  وظیفه انجام آن را دارد اعداد را به بازه -۶ الی ۶تبدیل میکنیم. با استفاده از سوئیچی که بر روی جوی استیک قرار دارد عملیات کلیک چپ و با استفاده از سوئیچی که بر روی برد برد قرار گرفته عملیات کلیک راست انجام می شود.

معرفی ماژول جوی استیک

ماژول جوی استیک PS2 آردوینو یک ماژول سخت‌افزاری است که به شما امکان اتصال یک جوی استیک نوع PS2 (در کنسول‌های بازی استفاده می‌شود) به برد آردوینو را می‌دهد. این ماژول از خروجی‌های آنالوگ برای دو محور (معمولاً محورهای X و Y) و خروجی‌های دیجیتال برای دکمه‌ها (دو دکمه در جوی استیک) استفاده می‌کند. اجزای اصلی ماژول جوی استیک، جوی استیک آنالوگ است. این استیک شامل دو پتانسیومتر (یکی برای هر محور) است که سیگنال‌های ولتاژ آنالوگی را تولید می‌کنند که به نسبت موقعیت جوی استیک در محورهای X و Y است.ماژول ممکن است یک یا چند دکمه فشاری داشته باشد که وقتی آن‌ها فشرده می‌شوند، خروجی‌های دیجیتالی تولید می‌کنند. این دکمه‌ها می‌توانند برای عملکردها و عملیات‌های مختلف در پروژه‌های آردوینو استفاده شوند.این ماژول دارای چند پین است که به شما اجازه می‌دهد آن را به برد آردوینو متصل کنید. این پین‌ها به شرح زیر برچسب‌گذاری می‌شوند:

• VCC: تامین تغذیه (۵ ولت از آردوینو).
• GND: زمین (زمین مشترک با آردوینو).
• VRx: خروجی آنالوگ محور X.
• VRy: خروجی آنالوگ محور Y.
• SW: خروجی دیجیتال دکمه‌ها.
• PS2_DAT، PS2_CMD، PS2_SEL، PS2_CLK: این‌ها برای اتصال جوی استیک با استفاده از رابط PS2 است (با آردوینو استفاده نمی‌شود).

بررسی پایه های ماژول جوی استیک

ماژول جوی استیک PS2 آردوینو دارای پنج پایه است که به شرح زیر هستند:

• VCC (تغذیه): این پایه برای تامین تغذیه ماژول استفاده می‌شود و به طور معمول به منبع تغذیه ۵ ولت آردوینو متصل می‌شود.

• GND (زمین): این پایه برای اتصال به زمین (GND) آردوینو استفاده می‌شود تا با آردوینو یک زمین مشترک داشته باشد.

• VRx (خروجی آنالوگ محور X): این پایه خروجی آنالوگ جوی استیک برای محور X است. زمانی که جوی استیک حرکت می‌کند، ولتاژ آنالوگ متناسب با موقعیت محور X تولید می‌شود که می‌تواند با استفاده از تابع analogRead() در آردوینو خوانده شود.

• VRy (خروجی آنالوگ محور Y): این پایه خروجی آنالوگ جوی استیک برای محور Y است. همانند پایه VRx، ولتاژ آنالوگ متناسب با موقعیت محور Y تولید می‌شود و با استفاده از تابع analogRead() در آردوینو قابل خواندن است.

• SW (خروجی دیجیتال دکمه‌ها): این پایه خروجی دیجیتال مربوط به دکمه‌های جوی استیک است. وقتی دکمه‌ها فشار داده می‌شوند، این پایه یک سیگنال دیجیتالی (HIGH یا LOW) تولید می‌کند که با استفاده از تابع digitalRead() در آردوینو قابل خواندن است.

کد آردوینو کنترل موس کامپیوتر با جوی استیک

این کد یک برنامه برای کنترل ماوس کامپیوتر با استفاده از یک جوی استیک آنالوگ است. کد را کپی و در نرم افزار آردوینو اجرا کنید.

#include <Mouse.h>
const int mouseButton = 3;    // کلیک چپ موس
const int rightMouseButton = 4;   //کلیک راست موس
const int xAxis = A0;         // xجوی استیک محور
const int yAxis = A1;         // yجوی استیک محور


int range = 12;               // محدوده مقدار حرکت موس
int responseDelay = 5;        // سرعت حرکت
int threshold = range / 4;      // مقدار آستانه حرکت
int center = range / 2;

boolean mouseIsActive = true;

void setup ()
  {
  //سوئیچ متصل به جوی استیک (کلیک چب) و همچنین سوئیچی که به منظور کلیک راست استفاده کرده اایم را در وضعیت پول آپ قرار میدهیم
  pinMode (mouseButton, 0);
  digitalWrite (mouseButton, 1);
  pinMode (rightMouseButton, 0);
  digitalWrite (rightMouseButton, 1);
  // موس را فعال میکنیم
  Mouse.begin ();
  }

void loop ()
  {

  /*
  که در قسمت پایین برنامه تعریف کرده ایم مقدار حرکت موس را حول محور ها تعیین میکنیم readAxis با استفاده از تابع

  این مقدار بین ۶ الی -۶ می باشد.
  */
  int xReading = readAxis (A0);
  int yReading = readAxis (A1);
  yReading *= -1;


  // در صورت فعال بودن موس ، موس  طبق مقادیر مشخص به حرکت در می آید
  if ( mouseIsActive )
    {
    Mouse.move (xReading, yReading, 0);
    }

  Serial.println (xReading);
  //,وضعیت کلیک چپ را بررسی میکنیم که آیا فشار داده شده است یا خیر

  if ( digitalRead (mouseButton) == LOW )
    {
    // اگر فشرده شده باشد ، فرمان کلیک کردن را صادر میکند
    if ( !Mouse.isPressed (MOUSE_LEFT) )
      {
      Mouse.press (MOUSE_LEFT);
      }
    }

  else {
  //در صورتی که کلیک چپ فشرده نشدده باشد ، فرمان رهایی کلیک چپ را صادر میکند
    if ( Mouse.isPressed (MOUSE_LEFT) )
      {
      Mouse.release (MOUSE_LEFT);
      }
    }

     // کد های  کلیک چپ همانند کد های کلیک راست می باشد
  if ( digitalRead (rightMouseButton) == LOW )
    {
    if ( !Mouse.isPressed (MOUSE_RIGHT) )
      {
      Mouse.press (MOUSE_RIGHT);
      }
    }
  else {
    if ( Mouse.isPressed (MOUSE_RIGHT) )
      {
      Mouse.release (MOUSE_RIGHT);
      }
    }
  delay (responseDelay);
  }

/*
این تابه مقدار انالوگ جوک استیک را میخواند و سپس آن را به مقادیری بین ۶ الی -۶ نسبت میدهد
*/

int readAxis (int thisAxis)
  {
  // مقدر آنالوگ را دریافت میکنیم
  int reading = analogRead (thisAxis);

  // مقدار آنالوگ پین را که بینن مقدار ۰ الی ۱۰۲۳ می باشد به مقدار ۰ الی ۱۲ نسبت میدهد
  reading = map (reading, 0, 1023, 0, range);


  int distance = reading - center;

 if (abs(distance) < threshold) {
    distance = 0;
  }

  // return the distance for this axis:
  return distance;
}

بررسی کتابخانه #include <Mouse.h>

تحلیل کد آردوینو

این کد یک برنامه برای کنترل ماوس کامپیوتر با استفاده از یک جوی استیک آنالوگ است. اجزای اصلی برنامه عبارتند از:

• تعریف و ابتدایی کردن متغیر‌ها و ثابت‌ها:mouseButton: پین مربوط به کلیک چپ موس.
  rightMouseButton: پین مربوط به کلیک راست موس.
  xAxis: پین مربوط به محور X جوی استیک آنالوگ.
  yAxis: پین مربوط به محور Y جوی استیک آنالوگ.
  range: محدوده حرکت موس، یعنی حداکثر مقداری که موس می‌تواند در هر جهت حرکت کند.
  responseDelay: سرعت حرکت موس.
  threshold: مقدار آستانه حرکت، اگر مقدار حرکت کمتر از این آستانه باشد، موس تحرک نمی‌کند.
  center: مرکز محور X و Y در جوی استیک، میانگین مقدار حرکت در اطراف این مرکز تشخیص داده می‌شود.
  mouseIsActive: متغیر منطقی برای فعال بودن یا غیرفعال بودن کنترل موس.

• setup():
  در این قسمت، پین‌های مربوط به کلیدهای جوی استیک (کلیک چپ و راست) به عنوان پین‌های ورودی تعریف و در حالت HIGH قرار داده می‌شوند.
  ماوس آغاز به کار می‌کند (Mouse.begin ()).

• loop():
  ابتدا مقادیر خوانده شده از جوی استیک در محور‌های X و Y آنالوگ در متغیر‌های xReading و yReading ذخیره می‌شوند. توجه داشته باشید که محور Y جوی استیک در این برنامه برعکس خوانده می‌شود (با تکرار yReading *= -1).
  اگر موس فعال باشد (mouseIsActive برابر با TRUE)، موس با استفاده از مقادیر xReading و yReading حرکت می‌کند.

• سپس وضعیت کلید کلیک چپ موس بررسی می‌شود:

اگر کلید کلیک چپ فشرده شود (مقدار دیجیتالی پین برابر با LOW باشد) و در حالتی که موس کلیک چپ فشرده نشده باشد (!Mouse.isPressed(MOUSE_LEFT)، یعنی کلیک چپ در حالت فشرده نشده قبلی نبوده باشد)، دستور کلیک چپ را صادر می‌کند (با Mouse.press(MOUSE_LEFT)).
اگر کلید کلیک چپ فشرده نشود (مقدار دیجیتالی پین برابر با HIGH باشد) و در حالتی که موس کلیک چپ فشرده بوده باشد (Mouse.isPressed(MOUSE_LEFT)، یعنی کلیک چپ در حالت فشرده بوده قبلی بوده باشد)، دستور رهایی کلیک چپ را صادر می‌کند (با Mouse.release(MOUSE_LEFT)).

نحوه کنترل کلیک راست موس نیز مشابه کلیک چپ است.در آخر دستور delay(responseDelay) برای تاخیر به اندازه responseDelay میلی‌ثانیه بین حرکات موس استفاده می‌شود.

سخت افزار مورد نیاز

آردوینو سری‌های DUE , LEONARDO , MICRO

جوی استیک دو محوره

یک عدد تاچ سوئیج

جمع بندی