آموزش ساخت بازی با آردوینو Arduino و LCD کاراکتری

بازی‌های الکترونیکی از دهه ۸۰ میلادی به عنوان بخشی از زندگی و اوقات فراغت تبدیل شدند. تراشه‌های الکترونیکی مختلفی در ایجاد بازی‌ها نقش آفرینی کرده‌اند. ترکیب بازی‌ها با نمایشگرهای کاراکتری، یکی از جذاب‌ترین موارد می‌باشد. همه علائم و موارد به صورت دو بعدی قابل اجرا هستند. در این آموزش روش ساخت یک بازی بسیار جذاب با استفاده از برد آردوینو، نمایشگر کاراکتری ۲×۱۶ و میکروسوئیچ خواهیم ساخت. در ادامه این آموزش با مرجع تخصصی آردوینو به زبان فارسی، دیجی اسپارک همراه باشید.

  

---

توضیحات بازی با آردوینو

---

در این بازی یک شخصیت کاراکتری در حال دویدن می‌باشد. با هر بار تحریک میکروسوئیچ آن شخص یک پرش انجام می‌دهد. در دو ردیف اجسام به شخص نزدیک می‌شوند؛ دراین بازی شخص باید با پریدن از روی اجسام پایینی و راه رفتن روی آن به بازی ادامه داده و با اجسام که نزدیک می‌شوند برخورد نکند. در بازی یک شمارنده وجود دارد که مدت زمان حضور شخص در بازی را نشان می‌دهد. همان امتیاز بازی می‌باشد. دقت کنید که این بازی بسیار اعتیاد آور می‌باشد. چون در این بازی هدف بر این است که شخص رکورد خودش را شکسته و رکورد جدیدی ثبت نماید. امیدوارم این آموزش انگیزه ای برای ساختن بازی‌های بیشتر با آردوینو باشد.

 

وسایل مورد نیاز

• ال سی دی کاراکتری ۱۶*۲
• پتانسیومتر (ولوم) ۵۰ کیلو اهم
• کلید (میکروسوئیچ)
• آردوینو uno
• برد بورد (bread bord)
• کابل فلت (نری به نری)

 

---

اتصالات مدار بازی با آردوینو

---

 

اتصالات lcd (نمایشگر)

پایه ی VCC  نمایشگر = پایه ی GND آردوینو

پایه ی VDD نمایشگر = پایه ی ۵ ولت آردوینو

پایه ی VO نمایشگر = پایه ی وسط پتانسیومتر (مقاومت متغییر)

پایه ی RS نمایشگر  = پایه ۸ آردوینو

پایه ی RW نمایشگر =پایه ی  GND آردوینو

پایه ی E نمایشگر = پایه ۹ آردوینو

پایه ی D4 نمایشگر = پایه ۱۰ آردوینو

پایه ی D5 نمایشگر = پایه ۱۱ آردوینو

پایه ی D6 نمایشگر = پایه ۱۲ آردوینو

پایه ی D7 نمایشگر = پایه ۱۳ آردوینو

پایه ی A نمایشگر = پایه ی ۵ ولت آردوینو

پایه ی K نمایشگر =  پایه ی GND آردوینو

 

 

اتصالات پتانسیومتر

پایه سمت راست = GND / 5V فرقی ندارد
پایه وسط = پایه ی VO نمایشگر
پایه سمت چپ = GND / 5V فرقی ندارد

 

اتصالات کلید

پایه اول = پایه ۷ آردوینو
پایه دوم = GND

 

---

کتابخانه بازی با آردوینو

---

همانطور که اشاره شد در این آموزش از نمایشگر LCD استفاده شده است. جهت راه اندازی ال سی دی کاراکتری به کتابخانه LiquidCrystal نیاز داریم. از اینرو بایستی این کتابخانه را دانلود و نصب کنیم. چنانچه روش نصب کتابخانه را نمی‌دانید، به آموزش نصب کتابخانه در نرم افزار آردوینو Arduino IDE مراجعه کنید. دو روش مجزا برای این موضوع کاملا توضیح داده شده است. روش فراخوانی کتابخانه هم مانند خط زیر می‌باشد.

#include <LiquidCrystal.h>

 

 

 

---

کدنویسی بازی با آردوینو

---

 

جهت اجرای پروژه کدهای زیر را در کامپایلر آردوینو Arduino IDE وارد کنید.

#include <LiquidCrystal.h> // برای استفاده از نمایشگر <LiquidCrystal.h> کتاب خانه 


// پیش کد (تعریف پایه ها)

#define BTN_PIN 7  // کلید 

#define SPRITE_RUN1 1
#define SPRITE_RUN2 2
#define SPRITE_JUMP 3
#define SPRITE_JUMP_UPPER '.'
#define SPRITE_JUMP_LOWER 4
#define SPRITE_TERRAIN_EMPTY ' ' 
#define SPRITE_TERRAIN_SOLID 5
#define SPRITE_TERRAIN_SOLID_RIGHT 6
#define SPRITE_TERRAIN_SOLID_LEFT 7

#define HERO_HORIZONTAL_POSITION 1    // موقعیت افقی قهرمان بر روی صفحه نمایش

#define TERRAIN_WIDTH 16
#define TERRAIN_EMPTY 0
#define TERRAIN_LOWER_BLOCK 1
#define TERRAIN_UPPER_BLOCK 2

#define HERO_POSITION_OFF 0          // قهرمان نامرئی است
#define HERO_POSITION_RUN_LOWER_1 1  // قهرمان در ردیف پایین اجرا می شود (حالت ۱)
#define HERO_POSITION_RUN_LOWER_2 2  // قهرمان در ردیف پایین اجرا می شود (حالت ۲) 

#define HERO_POSITION_JUMP_1 3       // شروع پرش
#define HERO_POSITION_JUMP_2 4       // نیمه راه بالا
#define HERO_POSITION_JUMP_3 5       // پرش در ردیف بالا است
#define HERO_POSITION_JUMP_4 6       // پرش در ردیف بالا است
#define HERO_POSITION_JUMP_5 7       // پرش در ردیف بالا است
#define HERO_POSITION_JUMP_6 8       // پرش در ردیف بالا است
#define HERO_POSITION_JUMP_7 9       // نیمه راه پایین
#define HERO_POSITION_JUMP_8 10      // در مورد زمین

#define HERO_POSITION_RUN_UPPER_1 11 // قهرمان در ردیف بالا اجرا می شود (حالت ۱)
#define HERO_POSITION_RUN_UPPER_2 12 // قهرمان در ردیف بالا اجرا می شود (حالت ۲)

// شروع کد ها از این قسمت
LiquidCrystal lcd(8, 9, 10, 11, 12, 13);        // پایه های lcd (8, 9, 10, 11, 12, 13)
static char terrainUpper[TERRAIN_WIDTH + 1];
static char terrainLower[TERRAIN_WIDTH + 1];
static bool buttonPushed = false;

void setup() {
  initializeGraphics();
  lcd.begin(16, 2);
  pinMode(BTN_PIN, INPUT_PULLUP);
}

void loop() {

  static byte heroPos = HERO_POSITION_RUN_LOWER_1;
  static byte newTerrainType = TERRAIN_EMPTY;
  static byte newTerrainDuration = 1;
  static bool playing = false;
  static bool blink = false;
  static unsigned int distance = 0;

  // بررسی کلید
  if ( digitalRead(BTN_PIN) == LOW ) {
    buttonPushed = true;
  }

  // نمایش صفحه شروع اگر در حال حاضر بازی نیست
  if (!playing) {
    drawHero((blink) ? HERO_POSITION_OFF : heroPos, terrainUpper, terrainLower, distance >> 3);
    if (blink) {
      lcd.setCursor(0, 0);
      lcd.print("Press Start");
    }
    delay(250);
    blink = !blink;
    if (buttonPushed) {
      initializeGraphics();
      heroPos = HERO_POSITION_RUN_LOWER_1;
      playing = true;
      buttonPushed = false;
      distance = 0;
    }
    return;
  }

  // تعویض زمین از سمت چپ
  advanceTerrain(terrainLower, newTerrainType == TERRAIN_LOWER_BLOCK ? SPRITE_TERRAIN_SOLID : SPRITE_TERRAIN_EMPTY);
  advanceTerrain(terrainUpper, newTerrainType == TERRAIN_UPPER_BLOCK ? SPRITE_TERRAIN_SOLID : SPRITE_TERRAIN_EMPTY);

  // طراحی زمین جدید به سمت راست
  if (--newTerrainDuration == 0) {
    if (newTerrainType == TERRAIN_EMPTY) {
      newTerrainType = (random(3) == 0) ? TERRAIN_UPPER_BLOCK : TERRAIN_LOWER_BLOCK;
      newTerrainDuration = 2 + random(10);
    } else {
      newTerrainType = TERRAIN_EMPTY;
      newTerrainDuration = 10 + random(10);
    }
  }

  // پرش کند اگر دکمه فشار داده شد
  if (buttonPushed) {
    if (heroPos <= HERO_POSITION_RUN_LOWER_2) heroPos = HERO_POSITION_JUMP_1;
    buttonPushed = false;
  }

  // اگر قهرمان با مانع برخورد کرد بازی متوقف شود
  if (drawHero(heroPos, terrainUpper, terrainLower, distance >> 3)) {
    playing = false; 
  } else {
    if (heroPos == HERO_POSITION_RUN_LOWER_2 || heroPos == HERO_POSITION_JUMP_8) {
      heroPos = HERO_POSITION_RUN_LOWER_1;
    } else if ((heroPos >= HERO_POSITION_JUMP_3 && heroPos <= HERO_POSITION_JUMP_5) && terrainLower[HERO_HORIZONTAL_POSITION] != SPRITE_TERRAIN_EMPTY) {
      heroPos = HERO_POSITION_RUN_UPPER_1;
    } else if (heroPos >= HERO_POSITION_RUN_UPPER_1 && terrainLower[HERO_HORIZONTAL_POSITION] == SPRITE_TERRAIN_EMPTY) {
      heroPos = HERO_POSITION_JUMP_5;
    } else if (heroPos == HERO_POSITION_RUN_UPPER_2) {
      heroPos = HERO_POSITION_RUN_UPPER_1;
    } else {
      ++heroPos;
    }
    ++distance;
  }

  delay(100);
}

// نمای سفارشی برای گرافیک lcd
void initializeGraphics() {

  static byte graphics[] = {

    // موقعیت ۱ را اجرا کن
    B01100,
    B01100,
    B00000,
    B01110,
    B11100,
    B01100,
    B11010,
    B10011,

    // موقعیت ۲ را اجرا کن
    B01100,
    B01100,
    B00000,
    B01100,
    B01100,
    B01100,
    B01100,
    B01110,

    // پرش
    B01100,
    B01100,
    B00000,
    B11110,
    B01101,
    B11111,
    B10000,
    B00000,

    // پرش به سمت پایین
    B11110,
    B01101,
    B11111,
    B10000,
    B00000,
    B00000,
    B00000,
    B00000,

    // زمین
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,

    // زمین راست
    B00011,
    B00011,
    B00011,
    B00011,
    B00011,
    B00011,
    B00011,
    B00011,

    // زمین چپ
    B11000,
    B11000,
    B11000,
    B11000,
    B11000,
    B11000,
    B11000,
    B11000,
  };
  int i;

  // طراحی شخصیت با سرعت زیاد
  for (i = 0; i < 7; ++i) {
    lcd.createChar(i + 1, &graphics[i * 8]);
  }

  // زمینه را خالی کن
  for (i = 0; i < TERRAIN_WIDTH; ++i) {
    terrainUpper[i] = SPRITE_TERRAIN_EMPTY;
    terrainLower[i] = SPRITE_TERRAIN_EMPTY;
  }
}

// افزایش سطح زمین را به سمت چپ
void advanceTerrain(char* terrain, byte newTerrain) {
  for (int i = 0; i < TERRAIN_WIDTH; ++i) {
    char current = terrain[i];
    char next = (i == TERRAIN_WIDTH - 1) ? newTerrain : terrain[i + 1];
    switch (current) {
      case SPRITE_TERRAIN_EMPTY:
        terrain[i] = (next == SPRITE_TERRAIN_SOLID) ? SPRITE_TERRAIN_SOLID_RIGHT : SPRITE_TERRAIN_EMPTY;
        break;
      case SPRITE_TERRAIN_SOLID:
        terrain[i] = (next == SPRITE_TERRAIN_EMPTY) ? SPRITE_TERRAIN_SOLID_LEFT : SPRITE_TERRAIN_SOLID;
        break;
      case SPRITE_TERRAIN_SOLID_RIGHT:
        terrain[i] = SPRITE_TERRAIN_SOLID;
        break;
      case SPRITE_TERRAIN_SOLID_LEFT:
        terrain[i] = SPRITE_TERRAIN_EMPTY;
        break;
    }
  }
}

// قهرمان را برای بررسی تصادف از صفحه برمیدارد
bool drawHero(byte position, char* terrainUpper, char* terrainLower, unsigned int score) {

  bool collide = false;
  char upperSave = terrainUpper[HERO_HORIZONTAL_POSITION];
  char lowerSave = terrainLower[HERO_HORIZONTAL_POSITION];
  byte upper, lower;

  // حالت روح مناسب برای قهرمان (اجرا یا پرش)
  switch (position) {
    case HERO_POSITION_OFF:
      upper = lower = SPRITE_TERRAIN_EMPTY;
      break;
    case HERO_POSITION_RUN_LOWER_1:
      upper = SPRITE_TERRAIN_EMPTY;
      lower = SPRITE_RUN1;
      break;
    case HERO_POSITION_RUN_LOWER_2:
      upper = SPRITE_TERRAIN_EMPTY;
      lower = SPRITE_RUN2;
      break;
    case HERO_POSITION_JUMP_1:
    case HERO_POSITION_JUMP_8:
      upper = SPRITE_TERRAIN_EMPTY;
      lower = SPRITE_JUMP;
      break;
    case HERO_POSITION_JUMP_2:
    case HERO_POSITION_JUMP_7:
      upper = SPRITE_JUMP_UPPER;
      lower = SPRITE_JUMP_LOWER;
      break;
    case HERO_POSITION_JUMP_3:
    case HERO_POSITION_JUMP_4:
    case HERO_POSITION_JUMP_5:
    case HERO_POSITION_JUMP_6:
      upper = SPRITE_JUMP;
      lower = SPRITE_TERRAIN_EMPTY;
      break;
    case HERO_POSITION_RUN_UPPER_1:
      upper = SPRITE_RUN1;
      lower = SPRITE_TERRAIN_EMPTY;
      break;
    case HERO_POSITION_RUN_UPPER_2:
      upper = SPRITE_RUN2;
      lower = SPRITE_TERRAIN_EMPTY;
      break;
  }

  // تشخیص برخورد با زمین
  if (upper != ' ') {
    terrainUpper[HERO_HORIZONTAL_POSITION] = upper;
    collide = (upperSave == SPRITE_TERRAIN_EMPTY) ? false : true;
  }
  if (lower != ' ') {
    terrainLower[HERO_HORIZONTAL_POSITION] = lower;
    collide |= (lowerSave == SPRITE_TERRAIN_EMPTY) ? false : true;
  }

  // محاسبه ی ارقام مورد نیاز برای امتیاز
  byte digits = (score > 9999) ? 5 : (score > 999) ? 4 : (score > 99) ? 3 : (score > 9) ? 2 : 1;

  // طراحی صفحه
  terrainUpper[TERRAIN_WIDTH] = '\0';
  terrainLower[TERRAIN_WIDTH] = '\0';
  char temp = terrainUpper[16 - digits];
  terrainUpper[16 - digits] = '\0';
  lcd.setCursor(0, 0);
  lcd.print(terrainUpper);
  terrainUpper[16 - digits] = temp;
  lcd.setCursor(0, 1);
  lcd.print(terrainLower);

  // نمایش امتیاز در سمت راست بالا صفحه
  lcd.setCursor(16 - digits, 0);
  lcd.print(score);

  terrainUpper[HERO_HORIZONTAL_POSITION] = upperSave;
  terrainLower[HERO_HORIZONTAL_POSITION] = lowerSave;

  return collide;
}

 

پروژه

کاربران بایستی همین بازی را با استفاده از ماژول جوی استیک راه اندازی کنند که به وسیله ی ماژول جوی استیک شخصیت بازی را هدایت کنند. 

 

 

چنانچه در مراحل راه اندازی و انجام این پروژه با مشکل مواجه شدید، بدون هیچ نگرانی در انتهای همین پست، به صورت ثبت نظر سوالتان را مطرح کنید. من در سریع‌ترین زمان ممکن پاسخ رفع مشکل شما را خواهم داد. همچنین اگر ایرادی در کدها و یا مراحل اجرایی وجود دارند می‌توانید از همین طریق اطلاع رسانی کنید.

 

---

پروژه و دریافت بن ارسال رایگان

---

برای دریافت بن خرید از دانشجو کیت، کاربران بایستی با استفاده از وسایل این آموزش، پروژه را اجرا کرده و یا حتی مدار جدیدی تعریف کنید. سپس از اجرای کار فیلم گرفته و در شبکه‌های اجتماعی از جمله آپارات و اینستگرام، با هشتگ‌های دیجی_اسپارک   دانشجوکیت    digispark    daneshjookit منتشر کنند. سپس از طریق بخش نظرات در ادامه همین آموزش، جهت دریافت بن خرید ارسال رایگان به ارزش ۱۲۰۰۰ تومان از دانشجو کیت، لینک را زیر همین پست ارسال کنید.

 

در پایان نظرات و پیشنهادات خود را با ما درمیان بگذارید و با اشتراک گذاری این آموزش در شبکه های اجتماعی , از وبسایت دیجی اسپارک حمایت کنید.