آموزش خواندن کدهای تگ RFID با ماژول RC522 و آردوینو Arduino

نکنولوژی RFID یک روش برای مدیریت در لایه‌های مختلف است. با این تکنولوژی بدون اینکه از سنسورهای مرئی استفاده شود، عملیات عبور و مرور و یا شمارش انجام می‌شود. به عنوان مثال در نظر بگیرید، در یک ساختمان اداری که چندین بخش مختلف دارد، افراد سازمان بر اساس درجه شغلی‌شان به بخش‌های مختلف دسترسی پیدا می‌کنند. هر فردی با کارت شخصی‌اش میتواند به بخش‌های تعریف شده ورود کند. نوع دیگر کاربرد تکنولوژی RFID در کتابفروشی‌ها است. تمامی کتاب‌ها دارای یک تگ RFID نازک به صورت برچسب داخل جلد هستند.

چنانچه فرکانس این تگ Tag از چرخه خارج نشده باشد، با دستگاه‌های خواننده RFID در جلو در ورودی به هنگام خروج از فروشگاه شناسایی شده و آژیر به صدا در می‌آید. این روش در اکثر فروشگاه‌های بزرگ بجز کتابفروشی‌ها کاربرد دارد. نوع دیگر کاربرد تکنولوژی rfid در چرخه تولید است. پالت‌های کالا از مواد اولیه در انبار گرفته تا انجام فرآیندهای مختلف در بخش‌های مختلف کارخانه توسط تگ‌های RFID با رنج فرکانسی قوی‌تر قابل ردیابی خواهند بود. برای آشنایی با انواع کاربرد RFID پیشنهاد میکنم به پست RFID چیست در وب سایت همکارانم علم فردا مراجعه کنید. در ادامه آموزش خواندن کدهای تگ RFID با مرجع تخصصی آردوینو به زبان فارسی، دیجی اسپارک همراه باشید.

ساختار ماژول کارت خوان RFID

RFID مخفف Radio frequency identification می‌باشد. این ماژول دارای ۸ پایه برای برقراری ارتباط با برد آردوینو Arduino است. فرکانس کاری ماژول RFID در باند ۱۳٫۵۶ مگاهرتز می‌باشد. ولتاژ کاری آن ۳٫۳ ولت بوده و جریان آن بین ۱۳ تا ۲۶ میلی آمپر است. پروتکل ارتباطی SPI و ماکزیمم سرعت آن ۱۰Mbit/S می‌باشد. قبلا در پست MRFC522 ماژول RFID آردوینو بخش اول به بررسی کامل این ماژول پرداخته ایم. در صورت نیاز مطالعه نمایید.

اتصالات ماژول RFID به آردوینو Arduino

ماژول RFID RC522  دارای ۸ پین می باشد که به ترتیب به آردوینو اتصال می‌دهیم:

پین SDA  Data line را به پین ۱۰ (Digital)  آردوینو وصل میکنیم.

پینSCK serial clock را به پین ۱۳ (Digital) آردوینو وصل میکنیم.

پین MOSI Master out slave in را به پبن ۱۱(Digital) آردوینو وصل میکنیم.

پین MISO Master in slave out را به پبن ۱۲ (Digital) آردوینو وصل میکنیم.

پین  RST RESET را به پین ۹(Digital) آردوینو وصل میکنیم.

پین GND  را به GND  آردوینو وصل کنید.

پین VCC را به پین ۳٫۳ ولت آردوینو وصل کنید.

فراخوانی کتابخانه

در این آموزش از کتابخانه MFRC522 استفاده می‌کنیم. لینک دانلود کتابخانه RC522 در صفحه محصول ماژول کارت خوان با قابلیت خواندن و نوشتن RFID – RC522 قسمت دانلود قرار دارد. چنانچه شیوه نصب کتابخانه در آردوینو را نمیدانید از پست نصب کنابخانه در نرم افزار آردوینو Arduino IDE استفاده کنید.

کد برنامه RFID

کد را در نرم افزار آردوینو کپی، کامپایل و سپس آپلود کنید. سپس سریال مانیتور Serial monitor نرم افزار آردوینو Arduino IDE را باز کنید. حال با نزدیک کردن کارت RFID و یا تگ RFID Tag به سنسور RFID ، کد آن بر روی سریال مانیتور نمایش داده می‌شود.

#include <SPI.h>
#include <MFRC522.h>

constexpr uint8_t RST_PIN = 9;     // Configurable, see typical pin layout above
constexpr uint8_t SS_PIN = 10;     // Configurable, see typical pin layout above
 
MFRC522 rfid(SS_PIN, RST_PIN); // Instance of the class

MFRC522::MIFARE_Key key; 

// Init array that will store new NUID 
byte nuidPICC[4];

void setup() { 
  Serial.begin(9600);
  SPI.begin(); // Init SPI bus
  rfid.PCD_Init(); // Init MFRC522 

  for (byte i = 0; i < 6; i++) {
    key.keyByte[i] = 0xFF;
  }

  Serial.println(F("This code scan the MIFARE Classsic NUID."));
  Serial.print(F("Using the following key:"));
  printHex(key.keyByte, MFRC522::MF_KEY_SIZE);
}
 
void loop() {

  // Look for new cards
  if ( ! rfid.PICC_IsNewCardPresent())
    return;

  // Verify if the NUID has been readed
  if ( ! rfid.PICC_ReadCardSerial())
    return;

  Serial.print(F("PICC type: "));
  MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
  Serial.println(rfid.PICC_GetTypeName(piccType));

  // Check is the PICC of Classic MIFARE type
  if (piccType != MFRC522::PICC_TYPE_MIFARE_MINI &&  
    piccType != MFRC522::PICC_TYPE_MIFARE_1K &&
    piccType != MFRC522::PICC_TYPE_MIFARE_4K) {
    Serial.println(F("Your tag is not of type MIFARE Classic."));
    return;
  }

  if (rfid.uid.uidByte[0] != nuidPICC[0] || 
    rfid.uid.uidByte[1] != nuidPICC[1] || 
    rfid.uid.uidByte[2] != nuidPICC[2] || 
    rfid.uid.uidByte[3] != nuidPICC[3] ) {
    Serial.println(F("A new card has been detected."));

    // Store NUID into nuidPICC array
    for (byte i = 0; i < 4; i++) {
      nuidPICC[i] = rfid.uid.uidByte[i];
    }
   
    Serial.println(F("The NUID tag is:"));
    Serial.print(F("In hex: "));
    printHex(rfid.uid.uidByte, rfid.uid.size);
    Serial.println();
    Serial.print(F("In dec: "));
    printDec(rfid.uid.uidByte, rfid.uid.size);
    Serial.println();
  }
  else Serial.println(F("Card read previously."));

  // Halt PICC
  rfid.PICC_HaltA();

  // Stop encryption on PCD
  rfid.PCD_StopCrypto1();
}


/**
 * Helper routine to dump a byte array as hex values to Serial. 
 */
void printHex(byte *buffer, byte bufferSize) {
  for (byte i = 0; i < bufferSize; i++) {
    Serial.print(buffer[i] < 0x10 ? " 0" : " ");
    Serial.print(buffer[i], HEX);
  }
}

/**
 * Helper routine to dump a byte array as dec values to Serial.
 */
void printDec(byte *buffer, byte bufferSize) {
  for (byte i = 0; i < bufferSize; i++) {
    Serial.print(buffer[i] < 0x10 ? " 0" : " ");
    Serial.print(buffer[i], DEC);
  }
}

وسایل مورد نیاز

برد آردوینو  Arduino UNO

ماژول کارت خوان RFID RC522

کارت RFID  خواندن و نوشتن ۱۳٫۵۶KHz

کابل فلت نری به مادگی Male to Female

چنانچه در مراحل راه اندازی و انجام این پروژه با مشکل مواجه شدید، بدون هیچ نگرانی در انتهای همین پست، به صورت ثبت نظر سوالتان را مطرح کنید. من در سریع‌ترین زمان ممکن پاسخ رفع مشکل شما را خواهم داد.

در پایان نظرات و پیشنهادات خود را با ما درمیان بگذارید و با اشتراک گذاری این آموزش در شبکه های اجتماعی , از وبسایت دیجی اسپارک حمایت کنید.