ویجت ایستگاه هواشناسی آردوینو Weather Station با نمایشگر Oled

ویجت‌ها ابزارهایی هستند که بر روی صفحه کامپیوتر یا موبایل و تبلت ما قرار دارند. ویجت‌ها به صورت خودکار شروع به کار کرده و همیشه در دسترس هستند. برای مثال ویجت نمایش رم رو بر گوشی تلفن یا تبلت را در نظر بگیرید، همیشه فعال و در حال ارسال یک سری اطلاعات از عملکرد گوشی هستند. این اطلاعات به عنوان یک دستیار به کاربران کمک می‌کند. از جمله موارد مشابه که هر روزه با آن سرو کار دارید. ویجت ساعت، پخش موسیقی، آب و هوا و یا آلارم ساعت هستند. قصد داریم یک ویجت فیزیکی با استفاده از برد آردوینو و نمایشگر Oled طراحی کنیم. این ویجت کوچک با مصرف بسیار ناچیز انرژی و ابعاد کوچک روی میز ما قرار می‌گیرد. سپس به عنوان دستیار همیشگی در حوزه آب و هوا و پیش بینی وضعیت آب و هوا به ما کمک خواهد کرد. در ادامه این آموزش با مرجع تخصصی آردوینو به زبان فارسی، دیجی اسپارک همراه باشید.

ویجت ایستگاه هواشناسی رومیزی

چه کنیم که یک ویجت را از کامپیوتر به روی میز منتقل کنیم؟ در این پروژه خیلی ساده و کاربردی ویجت ایستگاه هواشناسی را به همراه ساعت به روی میز منتقل می‌کنیم. با این روش همیشه آب و هوا و ساعت را از طریق این گجت خواهیم داشت. با این روش همیشه وضعیت آب و هوایی را به صورت پیش بینی شده خواهید داشت. اما قبل از شروع پروژه جهت درک بهتر این موضوع نیاز است تا چند مطلب را با هم مرور کنیم.

ویجت به عنوان گجت رومیزی

در گذشته، کاربران کامپیوترها و نرم افزارها تنها انسان‌ها بودند. رابط کاربری انسان‌ها با کامپیوتر User Interface توسط خود انسان، شکل می‌گرفت. در این ارتباط، کاربر اطلاعات را در صفحه روبروی خود می‌بیند، سپس پردازش کرده و نسبت به آن تصمیم می‌گیرد. اما امروزه این تعامل برای برقراری ارتباط میان این دنیایی که ابزارهای دیجیتالی نقش پررنگی را در زندگی روزمره ما دارند کافی نیست. در همین خصوص رابطی برای ارتباط مستقیم نرم افزارها با یکدیگر به وجود آمد. با نام API یا Application Programming Interface شناخته می‌شود. با این رابط، نرم افزارها می‌توانند اطلاعاتی را که نیاز دارند، به صورت خودکار از یک پایگاه داده بگیرند. یا به یک پایگاه داده انتقال دهند. یا حتی نرم افزارها با هم ارتباط برقرار کنند.

دراین ویجت رومیزی که به کمک یک برد wemos D1 mini به شبکه اینترنت متصل است. با استفاده از رابط API اطلاعات دقیق ساعت، تاریخ، دما و آب و هوای سه روز آینده را از یک پایگاه داده گرفته و بر روی یک Oled نمایش می‌دهد. برای اینکه بتوانم آن را بر روی میز قرار دهم و یک ویجت جذاب داشته باشم. پوسته‌ای خارجی، با نرم افزار کتیا طراحی کردم. سپس این طرح را با پرینتر سه بعدی، پرینت گرفتم. نمونه طرح و تصاویر نهایی را در ادامه خواهید دید. با نرم افزارهای طراحی سه بعدی مانند Catia, Solid Works, Aoutocad و … می توانید آن چه را که در ذهن دارید طراحی کنید. سپس به کمک پرینترهای سه بعدی به دنیای واقعی دعوتشان کنید. در تصویر زیر طرح ویجت ایستگاه هواشناسی آردوینو را که من در کتیا طراحی کرده‌ام، مشاهده می‌کنید.

لوازم مورد نیاز 

در این پروژه به یک برد wemos D1 mini و یک ماژول نمایشگر OLED با پروتکل ارتباطی I2C درایور SSD1306 نیاز دارید. تا بتوانید اطلاعات را بر روی آن نمایش دهید.

اتصالات ایستگاه هواشناسی آردوینو

نمایشگر oled از نوع i2C دارای ۴ عدد پایه اتصال دارد. اتصالات را طبق الگوی زیر برقرار کنید. چنانچه در مورد این نمایشگر اطلاعات بیشتری نیاز دارید. به پست آموزش راه‌اندازی نمایشگر OLED آردوینو بخش اول یا آموزش کار با ماژول OLED گرافیکی بخش اول نمایشگر ۱۲۸X32 رابط I2C مراجعه کنید. پس از برقرار کردن اتصالات، کافیست کدهای برنامه را بر روی برد Wemos با استفاده از کامپایلر آردوینو IDE آپلود کنید.

GND Oled = GND Wemos

VDD Oled = +5V Wemos

SCK Oled = D4 Wemos

SDA = D3 Wemos

کتابخانه آردوینو برد Wemos

برای برقرار شدن ارتباط شما با یک شبکه‌ای که بتوانید از طریق رابط API اطلاعات را دریافت کنید. سپس بر روی نمایشگر نشان دهید، به تعدادی کتابخانه نیاز دارید. اگر کتابخانه‌ها را به Arduino IDE اضافه نکنید، در هنگام آپلود شدن کدها بر روی برد با خطا کتابخانه روبه رو خواهید شد. چنانچه روش نصب کتابخانه در آردوینو را نمی‌دانید، به پست نصب کتابخانه در آردوینو IDE مراجعه کنید.

#include <ESPWiFi.h>
#include <ESPHTTPClient.h>
#include <JsonListener.h>


#include <time.h>                  
#include <sys/time.h>                 
#include <coredecls.h>                  

#include "SSD1306Wire.h"
#include "OLEDDisplayUi.h"
#include "Wire.h"
#include "OpenWeatherMapCurrent.h"
#include "OpenWeatherMapForecast.h"
#include "WeatherStationFonts.h"
#include "WeatherStationImages.h"

دانلود کتابخانه‌های مورد نیاز

جهت اجرای کدهای آردوینو قبل از کامپایل می‌بایست کتابخانه های مورد نیاز در نرم افزار آردوینو نصب گردد. لینک دانلود کتابخانه ها در صفحه محصول برد Wemos mini D1 قرار گرفته شده است. فایل مربوطه را دانلود و سپس یک به یک در نرم افزار آردوینو نصب کنید.

برد wemos D1 mini بر پایه ESP8266 با ۴ مگابایت حافظه فلش

اتصال ویجت به اینترنت

برد از یک شبکه محلی wifi برای برقراری ارتباط با اینترنت استفاده می‌کند. برای ایجاد این ارتباط، نام مودم و کلمه عبور آن را در قسمتی که در زیر مشخص شده است وارد کنید. در قسمت WIFI SSID نام مودم و در قسمت WIFI PWD گذرواژه ی مودم را وارد کنید. چنانچه تمایل دارید اطلاعات چندین مودم را وارد کنید تا در صورت قطع شدن ارتباط Wifi، ایستگاه هواشناسی از کار نیافتد. به پست اتصال برد Nodemcu به چند مودم Wifi وای فای با تراشه ESP8266 مراجعه کنید.

// WIFI
const char* WIFI_SSID = "Irancell-TD-GP2101PLUS-4794";
const char* WIFI_PWD = "lGaU2w97";

تنظیم ساعت به وقت محلی

زمانی که برد آردوینو با یک نرم افزار یا پایگاه داده جهت خواندن ساعت با رابط API ارتباط برقرار می‌کند. زمان را بر اساس زمان جهانی Greeanwich Mean Time می‌خواند. برای داشتن ساعتی دقیق، باید اختلاف زمان کشور محل سکونت را با زمان جهانی در قسمت زیر وارد کنید. 

#define TZ             +4.30     // (utc+) TZ in hours

کد ایستگاه هواشناسی آردوینو

کدهای زیر را کپی کرده و از طریق نرم افزار Arduino IDE روی برد آپلود کنید. دقت داشته باشید که کلیه موارد قبلی را باید به درستی اجرا کرده باشید. در غیر این صورت به هنگام آپلود با مشکل مواجه خواهید شد.

/**The MIT License (MIT)
Copyright (c) 2018 by Daniel Eichhorn - ThingPulse
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
See more at https://thingpulse.com

*****منتشر کردن این کد با رعایت حق کپی رایتی که در بالای متن قرار گرفته است بلامانع است*****
*/

#include <ESPWiFi.h>
#include <ESPHTTPClient.h>
#include <JsonListener.h>


#include <time.h>                  
#include <sys/time.h>                 
#include <coredecls.h>                  

#include "SSD1306Wire.h"
#include "OLEDDisplayUi.h"
#include "Wire.h"
#include "OpenWeatherMapCurrent.h"
#include "OpenWeatherMapForecast.h"
#include "WeatherStationFonts.h"
#include "WeatherStationImages.h"


/***************************
 * Begin Settings
 **************************/

// WIFI
const char* WIFI_SSID = "Irancell-TD-GP2101PLUS-4794";
const char* WIFI_PWD = "lGaU2w97";

#define TZ             +4.30     // (utc+) TZ in hours
#define DST_MN          12      // use 60mn for summer time in some countries

// Setup
const int UPDATE_INTERVAL_SECS = 20 * 60; // Update every 20 minutes

// Display Settings
const int I2C_DISPLAY_ADDRESS = 0x3c;
#if defined(ESP8266)
const int SDA_PIN = D3;
const int SDC_PIN = D4;
#else
const int SDA_PIN = 5; //D3;
const int SDC_PIN = 4; //D4;
#endif


// OpenWeatherMap Settings
// Sign up here to get an API key:
// https://docs.thingpulse.com/how-tos/openweathermap-key/
String OPEN_WEATHER_MAP_APP_ID = "771a886812cdc9340c21561040142b40";
/*
Go to https://openweathermap.org/find?q= and search for a location. Go through the
result set and select the entry closest to the actual location you want to display 
data for. It'll be a URL like https://openweathermap.org/city/2657896. The number
at the end is what you assign to the constant below.
 */
String OPEN_WEATHER_MAP_LOCATION_ID = "112931";

// Pick a language code from this list:
// Arabic - ar, Bulgarian - bg, Catalan - ca, Czech - cz, German - de, Greek - el,
// English - en, Persian (Farsi) - fa, Finnish - fi, French - fr, Galician - gl,
// Croatian - hr, Hungarian - hu, Italian - it, Japanese - ja, Korean - kr,
// Latvian - la, Lithuanian - lt, Macedonian - mk, Dutch - nl, Polish - pl,
// Portuguese - pt, Romanian - ro, Russian - ru, Swedish - se, Slovak - sk,
// Slovenian - sl, Spanish - es, Turkish - tr, Ukrainian - ua, Vietnamese - vi,
// Chinese Simplified - zh_cn, Chinese Traditional - zh_tw.
String OPEN_WEATHER_MAP_LANGUAGE = "en";
const uint8_t MAX_FORECASTS = 4;

const boolean IS_METRIC = true;

// Adjust according to your language
const String WDAY_NAMES[] = {"SUN", "MON", "TUE", "WED", "THU", "FRI", "SAT"};
const String MONTH_NAMES[] = {"JAN", "FEB", "MAR", "APR", "MAY", "JUN", "JUL", "AUG", "SEP", "OCT", "NOV", "DEC"};

/***************************
 * End Settings
 **************************/
 // Initialize the oled display for address 0x3c
 // sda-pin=14 and sdc-pin=12
 SSD1306Wire     display(I2C_DISPLAY_ADDRESS, SDA_PIN, SDC_PIN);
 OLEDDisplayUi   ui( &display );

OpenWeatherMapCurrentData currentWeather;
OpenWeatherMapCurrent currentWeatherClient;

OpenWeatherMapForecastData forecasts[MAX_FORECASTS];
OpenWeatherMapForecast forecastClient;

#define TZ_MN           ((TZ)*60)
#define TZ_SEC          ((TZ)*3600)
#define DST_SEC         ((DST_MN)*60)
time_t now;

// flag changed in the ticker function every 10 minutes
bool readyForWeatherUpdate = false;

String lastUpdate = "--";

long timeSinceLastWUpdate = 0;

//declaring prototypes
void drawProgress(OLEDDisplay *display, int percentage, String label);
void updateData(OLEDDisplay *display);
void drawDateTime(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawCurrentWeather(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawForecast(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y);
void drawForecastDetails(OLEDDisplay *display, int x, int y, int dayIndex);
void drawHeaderOverlay(OLEDDisplay *display, OLEDDisplayUiState* state);
void setReadyForWeatherUpdate();


// Add frames
// this array keeps function pointers to all frames
// frames are the single views that slide from right to left
FrameCallback frames[] = { drawDateTime, drawCurrentWeather, drawForecast };
int numberOfFrames = 3;

OverlayCallback overlays[] = { drawHeaderOverlay };
int numberOfOverlays = 1;

void setup() {
  Serial.begin(115200);
  Serial.println();
  Serial.println();

  // initialize dispaly
  display.init();
  display.clear();
  display.display();

  //display.flipScreenVertically();
  display.setFont(ArialMT_Plain_10);
  display.setTextAlignment(TEXT_ALIGN_CENTER);
  display.setContrast(255);

  WiFi.begin(WIFI_SSID, WIFI_PWD);

  int counter = 0;
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
    display.clear();
    display.drawString(64, 10, "Lets Get Online");
    display.drawXbm(46, 30, 8, 8, counter % 3 == 0 ? activeSymbole : inactiveSymbole);
    display.drawXbm(60, 30, 8, 8, counter % 3 == 1 ? activeSymbole : inactiveSymbole);
    display.drawXbm(74, 30, 8, 8, counter % 3 == 2 ? activeSymbole : inactiveSymbole);
    display.display();

    counter++;
  }
  // Get time from network time service
  configTime(TZ_SEC, DST_SEC, "pool.ntp.org");

  ui.setTargetFPS(30);

  ui.setActiveSymbol(activeSymbole);
  ui.setInactiveSymbol(inactiveSymbole);

  // You can change this to
  // TOP, LEFT, BOTTOM, RIGHT
  ui.setIndicatorPosition(RIGHT);

  // Defines where the first frame is located in the bar.
  ui.setIndicatorDirection(LEFT_RIGHT);

  // You can change the transition that is used
  // SLIDE_LEFT, SLIDE_RIGHT, SLIDE_TOP, SLIDE_DOWN
  ui.setFrameAnimation(SLIDE_RIGHT);

  ui.setFrames(frames, numberOfFrames);

  ui.setOverlays(overlays, numberOfOverlays);

  // Inital UI takes care of initalising the display too.
  ui.init();

  Serial.println("");

  updateData(&display);

}

void loop() {

  if (millis() - timeSinceLastWUpdate > (1000L*UPDATE_INTERVAL_SECS)) {
    setReadyForWeatherUpdate();
    timeSinceLastWUpdate = millis();
  }

  if (readyForWeatherUpdate && ui.getUiState()->frameState == FIXED) {
    updateData(&display);
  }

  int remainingTimeBudget = ui.update();

  if (remainingTimeBudget > 0) {
    // You can do some work here
    // Don't do stuff if you are below your
    // time budget.
    delay(remainingTimeBudget);
  }


}

void drawProgress(OLEDDisplay *display, int percentage, String label) {
  display->clear();
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  display->drawString(64, 10, label);
  display->drawProgressBar(2, 28, 124, 10, percentage);
  display->display();
}

void updateData(OLEDDisplay *display) {
  drawProgress(display, 10, "your place & you");
  drawProgress(display, 30, "Hello, who's there, I'm talking");
  currentWeatherClient.setMetric(IS_METRIC);
  currentWeatherClient.setLanguage(OPEN_WEATHER_MAP_LANGUAGE);
  currentWeatherClient.updateCurrentById(&currentWeather, OPEN_WEATHER_MAP_APP_ID, OPEN_WEATHER_MAP_LOCATION_ID);
  drawProgress(display, 80, "starting");
  forecastClient.setMetric(IS_METRIC);
  forecastClient.setLanguage(OPEN_WEATHER_MAP_LANGUAGE);
  uint8_t allowedHours[] = {12};
  forecastClient.setAllowedHours(allowedHours, sizeof(allowedHours));
  forecastClient.updateForecastsById(forecasts, OPEN_WEATHER_MAP_APP_ID, OPEN_WEATHER_MAP_LOCATION_ID, MAX_FORECASTS);

  readyForWeatherUpdate = false;
  drawProgress(display, 100, "Done...");
  delay(500);
}



void drawDateTime(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  now = time(nullptr);
  struct tm* timeInfo;
  timeInfo = localtime(&now);
  char buff[16];


  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  String date = WDAY_NAMES[timeInfo->tm_wday];

  sprintf_P(buff, PSTR("%s, %02d/%02d/%04d"), WDAY_NAMES[timeInfo->tm_wday].c_str(), timeInfo->tm_mday, timeInfo->tm_mon+1, timeInfo->tm_year + 1900);
  display->drawString(64 + x, 5 + y, String(buff));
  display->setFont(ArialMT_Plain_24);

  sprintf_P(buff, PSTR("%02d:%02d:%02d"), timeInfo->tm_hour, timeInfo->tm_min, timeInfo->tm_sec);
  display->drawString(64 + x, 15 + y, String(buff));
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawCurrentWeather(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  display->setFont(ArialMT_Plain_10);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->drawString(64 + x, 38 + y, currentWeather.description);

  display->setFont(ArialMT_Plain_24);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
  String temp = String(currentWeather.temp, 1) + (IS_METRIC ? "°C" : "°F");
  display->drawString(60 + x, 5 + y, temp);

  display->setFont(Meteocons_Plain_36);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->drawString(32 + x, 0 + y, currentWeather.iconMeteoCon);
}


void drawForecast(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {
  drawForecastDetails(display, x, y, 0);
  drawForecastDetails(display, x + 44, y, 1);
  drawForecastDetails(display, x + 88, y, 2);
}

void drawForecastDetails(OLEDDisplay *display, int x, int y, int dayIndex) {
  time_t observationTimestamp = forecasts[dayIndex].observationTime;
  struct tm* timeInfo;
  timeInfo = localtime(&observationTimestamp);
  display->setTextAlignment(TEXT_ALIGN_CENTER);
  display->setFont(ArialMT_Plain_10);
  display->drawString(x + 20, y, WDAY_NAMES[timeInfo->tm_wday]);

  display->setFont(Meteocons_Plain_21);
  display->drawString(x + 20, y + 12, forecasts[dayIndex].iconMeteoCon);
  String temp = String(forecasts[dayIndex].temp, 0) + (IS_METRIC ? "°C" : "°F");
  display->setFont(ArialMT_Plain_10);
  display->drawString(x + 20, y + 34, temp);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
}

void drawHeaderOverlay(OLEDDisplay *display, OLEDDisplayUiState* state) {
  now = time(nullptr);
  struct tm* timeInfo;
  timeInfo = localtime(&now);
  char buff[14];
  sprintf_P(buff, PSTR("%02d:%02d"), timeInfo->tm_hour, timeInfo->tm_min);

  display->setColor(WHITE);
  display->setFont(ArialMT_Plain_10);
  display->setTextAlignment(TEXT_ALIGN_LEFT);
  display->drawString(0, 54, String(buff));
  display->setTextAlignment(TEXT_ALIGN_RIGHT);
  String temp = String(currentWeather.temp, 1) + (IS_METRIC ? "°C" : "°F");
  display->drawString(128, 54, temp);
  display->drawHorizontalLine(0, 52, 128);
}

void setReadyForWeatherUpdate() {
  Serial.println("ready");
  readyForWeatherUpdate = true;
}

چنانچه در مراحل راه اندازی و انجام این پروژه با مشکل مواجه شدید، بدون هیچ نگرانی در انتهای همین پست، به صورت ثبت نظر سوالتان را مطرح کنید. من در سریع‌ترین زمان ممکن پاسخ رفع مشکل شما را خواهم داد. همچنین اگر ایرادی در کدها و یا مراحل اجرایی وجود دارند می‌توانید از همین طریق اطلاع رسانی کنید.

پروژه و دریافت بن ارسال رایگان

برای دریافت بن خرید از دانشجو کیت، کاربران بایستی با استفاده از وسایل این آموزش، پروژه را اجرا کرده و یا حتی مدار جدیدی تعریف کنید. سپس از اجرای کار فیلم گرفته و در شبکه‌های اجتماعی از جمله آپارات و اینستگرام، با هشتگ‌های دیجی_اسپارک و دانشجوکیت  و digispark  و  daneshjookit منتشر کنند. سپس از طریق بخش نظرات در ادامه همین آموزش، جهت دریافت بن خرید ارسال رایگان به ارزش ۱۲۰۰۰ تومان از دانشجو کیت، لینک را زیر همین پست ارسال کنید. در پایان نظرات و پیشنهادات خود را با ما درمیان بگذارید و با اشتراک گذاری این آموزش در شبکه های اجتماعی , از وبسایت دیجی اسپارک حمایت کنید.